Тест датчиков температуры DS18B20

Наконец-то получил долгожданный "стартовый комплект" с Arduino Mega 2560, где имелась макетная плата и теперь можно было по-быстрому подключать к Ардуине всякую фигню и играться. Температурные датчики DS18B20, защищённые трубкой из нержавейки и с герметично припаянным отрезком кабеля, я заказывал отдельно и получил их неделю назад, но проверить удалось только теперь.





Эх, если бы лет 25 назад у меня была возможность вот так легко и просто макетировать! Подоткнул Ардуину к ноуту, к макетной плате, подоткнул датчики, пару резюков, залил скачанный скетч и вуаля! 10 минут и всё работает. Просто, быстро, без паяльника, на кухонном столе!

В комплекте не было резисторов 4.7 к, поэтому взял два по 10 к в параллель. У датчиков гибкие проводки просто зачистил, подкрутил и воткнул в макетку, без лужения. Сначала подключил только один датчик:

Всё завелось сразу, даже как-то скучно. Дебажный скетч вывел в монитор порта много ненужной инфы о датчике, пришлось закомментить всё лишнее, оставив только температуру.

Ну, теперь нужно найти тело с эталонной температурой. Искать долго не пришлось, так как эталонное тело у меня всегда в наличии :) . Не долго думая, сунул датчик себе в рот (нет, датчик не мыл, но тщательно протёр его краем футболки :) ) и сижу втыкаю в экран, как набирается температура.

Надо сказать, что сидеть пришлось долго. До 35-ти набежало быстро, а вот потом дело пошло куда медленнее. Но я же упорный экспериментатор! Хотя с китайским датчиком во рту, скорее, упоротый, что, впрочем, почти одно и то же в данном случае. Результатом остался доволен:

Точность показаний здесь 0.0625 градуса - это максимальная точность данного датчика, обеспечиваемая максимальным же 12-битным разрешением считываемых данных. Разрешение может быть загрублено (до 11, 10 или 9 бит) путём программирования регистра конфигурации датчика (хранящегося в EEPROM), что позволит повысить скорость конвертации температуры:

         Разрешение, бит:     12       11       10       9
Скорость конвертации, ms:     750      375      187.5    93.75
   Точность показаний, °:     0.0625   0.125    0.25     0.5

По умолчанию датчики настроены на 12-битное разрешение, что как нельзя лучше подходит, чтобы с ними поиграться. Продолжаю играться.

Теперь подключим второй датчик. Прелесть 1-Wire (как и многих других последовательных интерфейсов) в том, что все устройства цепляются на одну линию в параллель. Поэтому тупо втыкаю параллельно второй датчик - и всё сразу же работает!

Режим паразитного питания не проверял, хотя для практического применения он будет более удобен, так как позволяет использовать двухпроводный кабель для подключения датчиков, вместо трёхпроводного. Хотя и имеет ограничение по максимальной измеряемой температуре в +100°С, против +125°С при внешнем питании по третьему проводу.

Дальше мне захотелось проверить датчики на минус. Достал из морозилки пару аккумуляторов холода и тупо сунул датчики между ними:

Показания побежали вниз и достигли неплохого такого минуса:

Ну, что ещё, конечно же, кипящая вода! Эталон в 100°С. Сначала вскипятил чайник, снял его с подставки и сунул в него датчик:

Хрен там был, а не 100 градусов:

92°С и всё. Быстренько кипяток остывает. Ну и датчик довольно инерционный. Нет, меня это не устраивает, придётся измерять в процессе кипения. Подключил чайник прямо рядом с Ардуиной, открыл крышку, сунул датчик поглубже и стал упорно (упорото) кипятить:

Чайник, не будь дураком, при 100°С по собственному цифровому индикатору сразу же отключается, даже при открытой крышке (Vitek, йопта!), поэтому пришлось долго насиловать кнопку включения в ожидании роста показаний до заветных 100°С. Но, моему внутреннему перфекционисту не пришлось порадоваться, максимум, который я смог выжать из чайника:

Чёт потом только подумал, чего я второй-то датчик не сунул в чайник, может погрешность была бы другой. Хотя на столе я дождался того момента, когда оба датчика показывали в точности одно и то же значение. Впрочем, возможно что 99.62°С - это верные данные точки кипения, ведь я не учитываю текущее атмосферное давление, состав воды и прочую физику с химией.

Ухх! Наигрался вдоволь. Хорошие датчики, но очень инерционные. Выравнивание показаний требует около пяти минут, а то и побольше. Хотя грубые данные с точностью до 1-2 градусов можно получить уже через минуту. Нормально, для удалённого контроля температуры в бытовке лучше и не надо. Позже займусь их инсталляцией.

Библиотека для 1-Ware: OneWire.zip

Дебажный скетч:
 
#include <OneWire.h>

// OneWire DS18S20, DS18B20, DS1822 Temperature Example
//
// http://www.pjrc.com/teensy/td_libs_OneWire.html
//
// The DallasTemperature library can do all this work for you!
// http://milesburton.com/Dallas_Temperature_Control_Library

OneWire  ds(10);  // on pin 10 (a 4.7K resistor is necessary)

void setup(void) {
  Serial.begin(9600);
}

void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }

  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
 
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 

  ds.reset();
  ds.select(addr);
  ds.write(0x44, 1);        // start conversion, with parasite power on at the end
  
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
  
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad

  Serial.print("  Data = ");
  Serial.print(present, HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();

  // Convert the data to actual temperature
  // because the result is a 16 bit signed integer, it should
  // be stored to an "int16_t" type, which is always 16 bits
  // even when compiled on a 32 bit processor.
  int16_t raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // "count remain" gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    // at lower res, the low bits are undefined, so let's zero them
    if (cfg == 0x00) raw = raw & ~7;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw & ~3; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw & ~1; // 11 bit res, 375 ms
    //// default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}

Комментарии

Где все комментарии до 2018 года?

Этот блог переехал на платформу Blogger в апреле 2018 года. До этого момента блог существовал на платформе WordPress с отключенной возможностью комментирования по причине малой нагрузочной способности домашнего хостинга.